////////////////////////////////////////////////////
// modele du ver du bourgeon de l'épinette
///////////////////////////////////////////////////
//
// tracé dans l'espace des paramètres des zones à 1,2 ou 3 points d'équilibre (hors 0)
//
u=1.01:0.01:30;
q=-2*(u.^3)./(1-u.^2);
r=q./(-3*u.^2+2*q.*u-1);
xset('window',0)
clf()
plot2d(q,r)
xtitle('zones à 1, 2 ou 3 pts d''équilibre','q','r')
//
// exemple r=0.4 et q =10: études des 3 points d'équilibre
//
xset('window',1)
clf()
r=0.4;q=10;
deff('y=f(t,x)','y=r*x*(1-x/q)-x^2/(1+x^2)');
for i=1:20;
 y0=10*rand();
 t0=0;
 t=0:0.1:100;
 y=ode(y0,t0,t,f)
 plot2d(t,y,i)
end  
xtitle('evolution de la densité en fonction du pt initial','t','N')
//  
deff('y=fbis(u)','y=r*(1+u^2)*(q-u)-q*u');
disp('point fixe 1 (stable):');disp(fsolve(0.2,fbis));
disp('point fixe 2 (instable):');disp(fsolve(4,fbis));
disp('point fixe 3 (stable):');disp(fsolve(6,fbis));
