///// Equation de Poisson 1D avec condition Dirichlet //
//// Schema aux differences finies///////
//// Ordre de convergence pour le cas f(x)=sin(%pi x)//
///////////////////////////////////////////////////////
err=[];
for k=2:10
N=2^k;     // valeurs de N: 4, 8, 16,... 1024
dx=1/(N+1);
deff('y=f(x)','y=sin(%pi*x)')
A=zeros(N,N);
for i=2:N-1
    A(i,i)=2;
    A(i,i+1)=-1;
    A(i,i-1)=-1;
end
A(1,1)=2;A(N,N)=2;A(1,2)=-1;A(N,N-1)=-1;
A=1/(dx^2)*A;
//
// aussi: A=toeplitz([2,-1,zeros(1,N-2)]);
b=zeros(N,1);
for i=1:N
    b(i)=f(i*dx);
end
//
u=inv(A)*b// aussi: u=linsolve(A,-b)
//
deff('y=ue(x)','y=1/(%pi^2)*sin(%pi*x)')
x=0:dx:1;uapp=[0;u;0];usol=ue(x);
xex=0:0.001:1;uex=ue(xex);
if (k==2)  then   // trace dans le cas N=4
   figure(1)
   clf()
   plot2d(x,uapp,5)
   plot2d(x,uapp,-1)
   plot2d(xex,uex)
end 
//
err=[err,max(abs(uapp-usol'))];
end
figure(2)  // trace de l'erreur
clf()
plot2d1('gll',2.^(2:10),err,1);
plot2d1('gll',[10^1,10^2],[10^(-1),10^(-3)],2)
legends(['erreur','pente -2'],[1,2])
