function spectre(A)
vps = spec(A);
xbasc();
write(%io(2),'spectre:');disp(vps);
D=diag(diag(A));
E=tril(-A)+D;
F=triu(-A)+D;
//
//  methode de jacobi
JAC=inv(D)*(E+F);
vpj = spec(JAC);
write(%io(2),'jacobi:');disp(max(abs(vpj)));
//
//methode Gauss Seidel
GS=inv(D-E)*F;
vpg = spec(GS);
write(%io(2),'gauss seidel:');disp(max(abs(vpg)));
//
// methode gradient a pas optimal
rho=max(spec(A));
mu = min(spec(A));
theta=2/(rho+mu);
GR=eye(A)-theta.*A;
vpg = spec(GR);
write(%io(2),'gradient pas optimal:');disp(max(abs(vpg)));
//
// methode de relaxation
rhos=[];
omegas=0.1:0.1:2;
for omega=omegas
	RL=inv(D-omega.*E)*(((1-omega).* D) +(omega.* F) );
	rhos=[rhos max(abs(spec(RL)))];
end
plot2d(omegas',rhos');
xtitle('Evolution de rho en fonction de omega');


